; *** Playing some music
; *** Public Domain for all VecFreaks
; *** Commented & coded by man@sci.fi
; *** Thanks to Chris Salomon.

; *** The needed BIOS functions

WAITRECAL	       equ	$f192
INTENSITY	       equ	$f2ab
PRINTSTR	       equ	$f37a

DP2C8            equ	$f1af ; DP to RAM
MUSICFLAG        equ  $c856 ; Vectrex music flag
DOSOUND          equ	$f289	; BIOS sound routine
INITMUSICHECK	 equ	$f687 ; 

testmusic        equ	$fef8 ; Some music from ROM
                            ; (Melody Master)
                            ; Others : 
                            ; $fdd3 - Scramble
                            ; $fe38 - Solar Quest
                            ; $fd1d - Berzerk

	org    0

; *** Init block

	fcb    $67,$20
	fcc    "GCE MANU"
	fcb    $80
	fdb    musa             ; Music to play at start
	fdb    $f850
	fdb    $30b8
	fcc    "PLAY MUSIC"
	fcb    $80,$0

; *** Then the actual program 

playmusic
   	lda	#1	            ; Set music flag to 1
	sta	MUSICFLAG	      ; (about to play music)

play
    jsr	DP2C8       	; DP to RAM
	ldu	#testmusic		; get some music
    jsr   INITMUSICHECK   	; and init new notes
                            ; This is good to be
                            ; before Waitrecal

    jsr	WAITRECAL	      ; BIOS recalibration
	lda	#100		      ; 
	jsr	INTENSITY         ; Intensity to 100
	lda	#0                ; Y
	ldb	#-40              ; X
	ldu	#text		      ; Get the text
	jsr	PRINTSTR          ; Display the text

    jsr   DOSOUND           ; ROM function that does the
                            ; music playing
	lbra	play              ; Loop

text    
    fcc	"hhh VECTREX hhh"
	fcb	$80

musa	                  ; Start music that plays nothing
    fdb    $fee8
	fdb	 $fbe6
	fcb    $0,$80
	fcb    $0,$80